Post by witzo on Aug 2, 2014 19:17:47 GMT
"HI!Ware - Finding elaborate ways to do trivial things since 1987."
It's probably trivial and I can't see any use for it, but I managed to put 16 different colours in 16 adjacent pixels. Because I use one-pixel sprites, this can only work in one spot on the screen .
(one-on-one ->) (magnified ->)
It's probably trivial and I can't see any use for it, but I managed to put 16 different colours in 16 adjacent pixels. Because I use one-pixel sprites, this can only work in one spot on the screen .
(one-on-one ->) (magnified ->)
10 rem **** 310714 hi!ware ****
12 rem >petcat -w70 -o 16colours.prg -- 16colours.bas
14 rem http://www.c64-wiki.com/index.php/valxtended_color_mode
16 graphic2,0:rem basic omhoog naar $4000 en ruimte van $2000 tot $4000
18 graphic0,0:rem terug naar tekstweergave
20 scnclr
22 cs=8192:rem character set op 8192=$2000
24 fc=55296:rem foreground colour mem start
26 sm=1024:rem screen mem start
28 sd=3584:rem sprite data start
30 rem kopieer de eerste 64 karakters naar ram $2000
32 fast
34 fora=0to512:bank14:b=peek(53248+a):bank0:pokecs+a,b:nexta
36 rem wijzig screencode 27t/m30
38 fora=cs+(8*27)tocs+(8*30)+7:readb:pokea,b:next
40 data 0,0,0,0,0,0,2,0
42 data 0,0,0,0,0,0,64,0
44 data 0,2,0,0,0,0,0,0
46 data 0,64,0,0,0,0,0,0
48 poke217,4:rem lees chars uit ram ipv. uit rom
50 poke2604,peek(2604)and240or8:rem vertel comp dat chars op 8192/1024=8 staan
52 rem achtergrondkleurregisters
54 bank15
56 poke 53281,0:poke 53282,1:poke 53283,2:poke 53284,3
58 poke 53265,peek(53265) or 64:rem set bit 6 $d011 voor ebcm
60 rem poke 4 tekens in een vierkantje
62 pokesm+500,27:pokesm+501,28+64:pokesm+540,29+128:pokesm+541,30+192
64 rem poke de 4 tekens hun voorgrondkleur
66 pokefc+500,4:pokefc+501,5:pokefc+540,6:pokefc+541,7
68 rem alle sprites leegmaken
70 fora=sdtosd+512:bank0:pokea,0:bank15:nexta
72 rem alle sprites 1 pixel linksboven
74 fora=sdtosd+512step64:bank0:pokea,128:bank15:nexta
76 slow
78 rem alle sprites aan en op hun plaats
80 sprite1,1,9,0:movspr1,191,152
82 sprite2,1,10,0:movspr2,192,152
84 sprite3,1,11,0:movspr3,190,153
86 sprite4,1,12,0:movspr4,190,154
88 sprite5,1,13,0:movspr5,193,153
90 sprite6,1,14,0:movspr6,193,154
92 sprite7,1,15,0:movspr7,191,155
94 sprite8,1,16,0:movspr8,192,155
96 rem july 30, 2014
98 restore 200
100 t=0:i=0:c=1
102 do
104 read i
106 if i < 0 then exit
108 pokesm+t,i:t=t+1:pokefc+t,c:c=c+1
110 ifc=16thenc=4
112 loop
200 data 10,21,12,25,32,51,48,44,32,50,48,49,52,-1
202 rem hi!ware presents
204 restore 220
206 i=0:t=t+77
208 do
210 read i
212 if i < 0 then exit
214 pokesm+t,i+64:t=t+1:pokefc+t,c:c=c+1
216 ifc=16thenc=4
218 loop
220 data 32, 8,9,33,23,1,18,5,32,16,18,5,19,5,14,20,19,-1
222 rem sixteen colours
224 restore 240
226 i=0:t=t+64
228 do
230 read i
232 if i < 0 then exit
234 pokesm+t,i+128:t=t+1:pokefc+t,c:c=c+1
236 ifc=16thenc=4
238 loop
240 data 19,9,24,20,5,5,14,32,3,15,12,15,21,18,19,-1
242 rem in sixteen adjacent pixels.
244 restore 260
246 i=0:t=t+19
248 do
250 read i
252 if i < 0 then exit
254 pokesm+t,i+192:t=t+1:pokefc+t,c:c=c+1
256 ifc=16thenc=4
258 loop
260 data 9,14,32,19,9,24,20,5,5,14,32,1,4,10,1,3,5,14,20,32,16,9,24,5,12,19,46,-1
262 getkeya$