|
|
Post by VDC 8x2 on Jul 5, 2014 5:28:59 GMT
I was looking at my old VDC decompress code and thought of a new way to make it.
Source = $fe
destination = $fc
Temp = $fc
vdcadr = $d600
vdcdat = $d601
defm WAITVDC
bit $d600
bpl *-3
endm
*=$1300
Start ldx destination ;low byte
lda destination+1 ;high byte
ldy #$12
sty vdcadr
WAITVDC ;vdc ready?
sta vdcdat ;high byte dest
iny
sty vdcadr
stx vdcdat ;low byte set. destination is now set
MainLoop ldy #$00
lda (source),y
lsr ;get bit
bcs SkipCopy ;branch skip/copy test
lsr ;get next bit
bcs Fill ;branch to fill routine
rts ;end of file so bye bye
Fill tax ;bytes to fill always 2 to 63 or 0
dex ;never 1
lda #$18
sta vdcadr
lda vdcdat ;going to set to fill
and #$7f
sta vdcdat ;clear bit 7
jsr incsource
lda #$1f
sta vdcadr
WaitVdc ;wait for ready
lda (source),y ;byte to repeat
sta VDCDAT
lda #$1e
sta vdcadr
stx vdcdat ;start fill
jsr incsource
jmp MAINLOOP
SkipCopy lsr ;get bit
bcs Copy ;branch to Copy
tax ;transfer to x for counter. 0 will go 256 times.
lda #$1f
sta vdcadr
Waitvdc
@loop jsr IncSource ;get next byte
lda (source),y
WAITVDC ;vdc ready?
sta vdcdat ;store value
dex
beq @loop
jsr INCSOURCE ;we done so get get next byte
jmp MainLoop
Copy tax ;The copy routine copies -x bytes forwords +bytes
sta temp ;save for later
ldy #$13
sty vdcadr
lda vdcdat
sbc #$01 ;-1 to account for the autoinc of vdc
sbc temp ;low bite - value
sta temp ;we know carry is set
dey
sty vdcadr
waitvdc ;wait because reg 12
ldy vdcdat
bcs @next ;no borrow
dey
@next txa ;check value
bne @notzero ;0 is 256
dey
@notzero lda #$20
sta vdcadr
sty vdcdat ;store high byte
lda #$21
sta vdcadr
lda temp
sta vdcdat ;store low byte
lda #$18
sta vdcadr
lda vdcdat ;going set to copy
ora #$80
sta vdcdat ;clear bit 7
lda #$1e
sta vdcadr
stx vdcdat ;copy x bytes
jsr INCSOURCE ;update for next byte
jmp MainLoop
IncSource inc SOURCE
bne @end
inc source+1
@end rts
It starts by taking destination and putting it into the address registers.
Next, we load a byte from the source. The lower 2 bits are for signalling if copy,fill,skip or quit. They are stripped off via the lsr opcode.
After the stripping is done we are left with a number from 0 to 63, 0 will have the special meaning of 256
Skip will just pass along 1-63 or 256 bytes to vdc.
Fill will fill the vdc with a byte, 2 - 63 or 256 times
Copy is what is differnt, it will copy the last 1 to 63 bytes or 256 byte in vdc mem forwords once.
00 bits will just have the code exit.
I haven't compiled it fully yet. do you see any way to improve it or bugs that I missed?
|
|
|
|
Post by VDC 8x2 on Jul 5, 2014 15:17:18 GMT
Fixed a couple bugs. version 1.5 Source = $fe
destination = $fc
Temp = $fc
vdcadr = $d600
vdcdat = $d601
defm WAITVDC
bit $d600
bpl *-3
endm
*=$1300
Start lda destination+1 ;high byte
ldy #$12
sty vdcadr
WAITVDC ;vdc ready?
sta vdcdat ;high byte dest
iny
sty vdcadr
lda destination ;low byte
sta vdcdat ;low byte set. destination is now set
jmp First
MAINLOOP jsr incsource
First jsr Parse
waitvdc ;wait for copy or fill to finish
bmi MainLoop ;it is always minus after wait vdc so use it to branch to mainloop. saving a byte
Parse ldy #$00
lda (source),y
lsr ;get bit
bcs SkipCopy ;branc skip/copy test
lsr ;get next bit
bcs Fill ;branch to fill routine
pla ;done so popping return address off
pla ;stack
rts ;end of file so bye bye
Fill tax ;bytes to fill always 2 to 63 or 0
dex ;never 1
lda #$18
sta vdcadr
lda vdcdat ;going to set to fill
and #$7f
sta vdcdat ;clear bit 7
jsr incsource
lda #$1f
sta vdcadr
WaitVdc ;wait for ready
lda (source),y ;byte to repeat
sta VDCDAT
lda #$1e
sta vdcadr
stx vdcdat ;start fill
rts
SkipCopy lsr ;get bit
bcs Copy ;branch to Copy
tax ;transfer to x for counter
lda #$1f
sta vdcadr
@loop jsr IncSource ;get next byte
lda (source),y
WAITVDC ;vdc ready?
sta vdcdat ;store value
dex
beq @loop
rts
Copy tax ;copies -x bytes forwords +bytes
sta temp ;save for later
ldy #$13
sty vdcadr
lda vdcdat
sbc #$01 ;-1 to account for the autoinc of vdc
sbc temp ;low bite - value. we know carry is set
sta temp
dey
sty vdcadr
waitvdc ;wait because reg 12
ldy vdcdat
bcs @next ;carry used up?
dey
@next txa ;check value
bne @notzero ;0 is 256
dey
@notzero lda #$20 ;source for copy
sta vdcadr
sty vdcdat ;store high byte
lda #$21
sta vdcadr
lda temp
sta vdcdat ;store low byte
lda #$18
sta vdcadr
lda vdcdat ;going set to copy
ora #$80
sta vdcdat ;set bit 7
lda #$1e
sta vdcadr
stx vdcdat ;copy x bytes
rts
IncSource inc SOURCE
bne @end
inc source+1
@end rts Attachments:nuvdcpress.prg (206 B)
|
|
|
|
Post by VDC 8x2 on Jul 5, 2014 15:25:54 GMT
need to come up with a data stream that will test all the functions.
Edit:
best case compression on a 2000 byte text screen with all spaces on it, with no attributes.
13 bytes
$01,$20,$03,$03,$03,$03,$03,$03,$ff,$ff,$ff,$2f,$00
|
|
|
|
Post by hydrophilic on Jul 6, 2014 0:12:45 GMT
First, how is this different from your original? (Hint: because the old forum is no longer available, you can say almost anything... like it runs 200% faster  ) Second, yes, a good test program (or in this case, data source) is invaluable for testing effeciency of variations. P.S. I still need to update MP128 to use the more effecient LSR we discussed, and which you are now using. I suppose once I have the time to do this, I'll be able to give more constructive feedback about your code... but in the meantime, thanks for sharing! |
|
|
|
Post by VDC 8x2 on Jul 6, 2014 1:16:03 GMT
The main differences are: the lsr thing and the copy portion does 2 to 63 or 256 bytes instead of just 8 bytes. making copy more powerful then it used to be.
|
|
|
|
Post by hydrophilic on Jul 6, 2014 2:37:07 GMT
Cool... 256 doesn't occur VERY often, but when it does, this is sure to save a lot of CPU time (and a several bytes of the compressed data stream).
|
|
|
|
Post by VDC 8x2 on Jul 22, 2014 21:41:35 GMT
I made a small change to the code. during compression: 1 will now stand for 128. so for values 2 to 63 normal operation. 1 will be turned into 128. 0 will be turned into 256. Source = $fe
destination = $fc
Temp = $fc
vdcadr = $d600
vdcdat = $d601
defm WAITVDC
bit $d600
bpl *-3
endm
*=$1300
Start lda destination+1 ;high byte
ldy #$12
sty vdcadr
WAITVDC ;vdc ready?
sta vdcdat ;high byte dest
iny
sty vdcadr
lda destination ;low byte
sta vdcdat ;low byte set. destination is now set
jmp First
MAINLOOP jsr incsource
First jsr Parse
waitvdc ;wait for copy or fill to finish
bmi Mainloop ;we know it is always mi after vdcwait so use
;it.
Parse ldy #$00
lda (source),y
lsr ;get bit
bcs SkipCopy ;branc skip/copy test
lsr ;get next bit
bcs Fill ;branch to fill routine
pla ;done so popping return address off
pla ;stack
rts ;end of file so bye bye
Fill cmp #$01 ;is it 1
bne @not1
ror ;turn it into 128
@not1 tax
dex ;number of bites to fill. 2 to 63 or 128 or 256
lda #$18
sta vdcadr
lda vdcdat ;going to set to fill
and #$7f
sta vdcdat ;clear bit 7
jsr incsource
lda #$1f
sta vdcadr
WaitVdc ;wait for ready
lda (source),y ;byte to repeat
sta VDCDAT
lda #$1e
sta vdcadr
stx vdcdat ;start fill
rts
SkipCopy lsr ;get bit
bcs Copy ;branch to Copy
tax ;transfer to x for counter
lda #$1f
sta vdcadr
@loop jsr IncSource ;get next byte
lda (source),y
WAITVDC ;vdc ready?
sta vdcdat ;store value
dex
beq @loop
rts
Copy cmp #$01 ;is it 1
bne @not1
ror ;turn it into 128
@not1 tax ;copies -x bytes forwords +bytes
sta temp ;save for later
ldy #$13
sty vdcadr
lda vdcdat
sbc #$01 ;-1 to account for the autoinc of vdc
sbc temp ;low bite - value. we know carry is set
sta temp
dey
sty vdcadr
waitvdc ;wait because reg 12
ldy vdcdat
bcs @next ;carry used up?
dey
@next txa ;check value
bne @notzero ;0 is 256
dey
@notzero lda #$20 ;source for copy
sta vdcadr
sty vdcdat ;store high byte
lda #$21
sta vdcadr
lda temp
sta vdcdat ;store low byte
lda #$18
sta vdcadr
lda vdcdat ;going set to copy
ora #$80
sta vdcdat ;set bit 7
lda #$1e
sta vdcadr
stx vdcdat ;copy x bytes
rts
IncSource inc SOURCE
bne @end
inc source+1
@end rts Attachments:nuvdcpress2.prg (216 B)
|
|
|
|
Post by hydrophilic on Jul 23, 2014 3:06:19 GMT
I spy a bug: Fill cmp #$01 ;is it 1
bne @not1
ror
ror ;turn it into 128that would turn the accumulator into 192 because CMP sets the carry; should be LSR, ROR. EditOr you could turn that into a feature! Save 1 byte and 2 cycles insert code here
Fill cmp #$01 ;is it 1
bne @not1
ror ;turn it into 128 |
|
|
|
Post by VDC 8x2 on Jul 23, 2014 3:10:09 GMT
Ty for catching that. Edited the code and recompiled to use the 'feature'. |
|
|
|
Post by VDC 8x2 on Jul 23, 2014 21:57:10 GMT
I have tested my code. skip and fill are working like expected. The copy part is still giving me fits maybe the vdc is being the quirky.
I think I am going to have to reorder the register reads and check my subtraction.
The latest version of the code.
Source = $fd
destination = $fb
vdcadr = $d600
vdcdat = $d601
defm WAITVDC
bit $d600
bpl *-3
endm
*=$1300
Start lda destination+1 ;high byte
ldy #$12
sty vdcadr
WAITVDC ;vdc ready?
sta vdcdat ;high byte dest
iny
sty vdcadr
lda destination ;low byte
sta vdcdat ;low byte set. destination is now set
jmp First
MAINLOOP jsr incsource
First jsr Parse
waitvdc ;wait for copy or fill to finish
bmi Mainloop ;we know it is always mi after vdcwait so use
;it.
Parse ldy #$00
lda (source),y
lsr ;get bit
bcs SkipCopy ;branc skip/copy test
lsr ;get next bit
bcs Fill ;branch to fill routine
pla ;done so popping return address off
pla ;stack
rts ;end of file so bye bye
Fill cmp #$01 ;is it 1
bne @not1
ror ;turn it into 128
@not1 tax
dex ;number of bites to fill. 2 to 63 or 128 or 256
lda #$18
sta vdcadr
lda vdcdat ;going to set to fill
and #$7f
sta vdcdat ;clear bit 7
jsr incsource
lda #$1f
sta vdcadr
WaitVdc ;wait for ready
lda (source),y ;byte to repeat
sta VDCDAT
lda #$1e
sta vdcadr
stx vdcdat ;start fill
rts
SkipCopy lsr ;get bit
bcs Copy ;branch to Copy
tax ;transfer to x for counter
lda #$1f
sta vdcadr
@loop jsr IncSource ;get next byte
lda (source),y
WAITVDC ;vdc ready?
sta vdcdat ;store value
dex
bne @loop
rts
Copy cmp #$01 ;is it 1
bne @not1
ror ;turn it into 128
@not1 tax ;copies -x bytes forwords +bytes
bne @not2 ;is it 0
ldy #$01 ;set high byte to 1 if zero
@not2 sta destination ;low byte
sta destination+1 ;high byte
ldy #$13
sty vdcadr
lda vdcdat
sec
sbc #$01 ;-1 to account for the autoinc of vdc
sbc destination ;low bite - value.
sta destination
dey
sty vdcadr
waitvdc ;wait because reg 12
lda vdcdat
sbc destination+1
sta destination+1 ;saved the results
ldy #$20 ;source for copy
sty vdcadr
lda destination+1
waitvdc
sta vdcdat ;store high byte
iny
sty vdcadr
lda destination
sta vdcdat ;store low byte
lda #$18
sta vdcadr
lda vdcdat ;going set to copy
ora #$80
sta vdcdat ;set bit 7
lda #$1e
sta vdcadr
stx vdcdat ;copy x bytes
rts
IncSource inc SOURCE
bne @end
inc source+1
@end rts
|
|
)